Возможно ли Извлечь / Выбрать значение доп. реквизита номенклатуры?

Question

[AlexCruel]

Создается номенклатура при загрузки из файла. При этом необходимо добраться до дополнительного реквизита номенклатуры. Базовая номенклатура без категории не имеет некоторых реквизитов.
Пробую сделать так, но функция принимает числовой аргумент, который является индексом.

НоваяНоменклатура.ДополнительныеРеквизиты.Получить()

Можно ли как-то добраться до доп. реквизита, чтобы указать значение?

Comments

[Sgr_A]

Какая конфигурация?

[AlexCruel]

Sgr_A, редакция 1.6 (1.6.20.178)

[AlexCruel]

Sgr_A, 1С:Предприятие 8.3 (8.3.16.1148)

[Sgr_A]

Не понял... просто надо в новую номенклатуру доп. реквизит добавить? Который в предприятии создан?

[Sgr_A]

AlexCruel, это версия. А называется как? Бухгалтерия, Управление торговлей, Розница, УПП...

[AlexCruel]

Sgr_A, создаю через код номенклатуру, подтягиваются доп. реквизиты в зависимости от категории номенклатуры. Далее нужно указать значения доп. реквизитов. Например, "Производитель", который является списком (тип значения - Дополнительное значение).

Прошу прощения, если не точно отвечаю, т.к. обучаюсь. "Управление нашей фирмой".

Answer 1

[Михаил Е]

Если БСП внедрена (Бухгалтерия/УТ/ЕРП/УНФ) тогда так :

НаименованиеРеквизита = "";	 //Сюда вставить наименование реквизита
	ЗначениеРеквизита = ""; 		//Сюда вставить значение

	ВашРеквизит = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоНаименованию(НаименованиеРеквизита );

	ТаблицаДопРеквизитов = Новый ТаблицаЗначений;
	ТаблицаДопРеквизитов.Колонки.Добавить("Свойство", Новый ОписаниеТипов("ПланВидовХарактеристикСсылка.ДополнительныеРеквизитыИСведения"));
	ТаблицаДопРеквизитов.Колонки.Добавить("Значение");

	НоваяСтрокаЗначений = ТаблицаДопРеквизитов.Добавить();
	НоваяСтрокаЗначений.Свойство = ВашРеквизит;
	НоваяСтрокаЗначений.Значение= ЗначениеРеквизита ;
	УправлениеСвойствами.ЗаписатьСвойстваУОбъекта( НоваяНоменклатураСсылка, ТаблицаДопРеквизитов)

Comments

[Sgr_A]

Да, так. Только ссылку на ПВХ получать правильнее вот так:

ИмяДопРеквизита = "Производитель"; //Имя, которое идет в блоке "Для разработчиков" 
ВашРеквизит  = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоРеквизиту("Имя", ИмяДопРеквизита );

[AlexCruel]

Как указать ссылку на новую номенклатуру?

[Михаил Е]

AlexCruel
После записи, это будет "НоваяНоменклатура.Ссылка"

[AlexCruel]

Номенклатрура создается как прежде, но доп. реквизиты не перезаписываются

Для каждого СтрокаДанных Из Объект.ДанныеФайла Цикл
		// запись номенклатуры
		НоваяНоменклатура = Справочники.Номенклатура.СоздатьЭлемент();
		НоваяНоменклатура.КатегорияНоменклатуры = Справочники.КатегорииНоменклатуры.НайтиПоНаименованию(СтрокаДанных.КатегорияНоменклатуры);
		НоваяНоменклатура.ТипНоменклатуры = Перечисления.ТипыНоменклатуры.Запас;
		НоваяНоменклатура.Наименование = СтрокаДанных.Наименование;
		НоваяНоменклатура.Комментарий = СтрокаДанных.Наименование;
				
		НоваяНоменклатура.Записать();
		
		// запись свойств номенклатуры 
		РеквизитДляЗаписи = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоНаименованию("Предполагаемый срок эксплуатации");
		Сообщить(РеквизитДляЗаписи);
		
		ТаблицаДопРеквизитов = Новый ТаблицаЗначений;
		ТаблицаДопРеквизитов.Колонки.Добавить("Свойство", Новый ОписаниеТипов("ПланВидовХарактеристикСсылка.ДополнительныеРеквизитыИСведения"));
		ТаблицаДопРеквизитов.Колонки.Добавить("Значение");

		НоваяСтрокаЗначений = ТаблицаДопРеквизитов.Добавить();
		НоваяСтрокаЗначений.Свойство = РеквизитДляЗаписи;
		НоваяСтрокаЗначений.Значение= "10";
		УправлениеСвойствами.ЗаписатьСвойстваУОбъекта(НоваяНоменклатура.Ссылка, ТаблицаДопРеквизитов);

	КонецЦикла;

[Михаил Е]

AlexCruel
1. "Сообщить(РеквизитДляЗаписи);" - Сообщает ? (т.е. реквизит нашелся ?)
2. "НоваяСтрокаЗначений.Значение= "10";" - думаю там тип "Число", т.е. должно быть
НоваяСтрокаЗначений.Значение = 10;

[AlexCruel]

Михаил Е,
1. да, сообщает
2. вводил числом (так как числовой тип), и стрингом. Не записывает. Пробовал для другого реквизита, у которого тип значения "Дополнительные значения" с существующим значением - то же самое

[AlexCruel]

Михаил Е,
Может быть, что после записи не все обязательные реквизиты заполнены. Сейчас вручную пробовал указать, пишет, что не все заполнено

[Михаил Е]

AlexCruel
Только что проверил - работает.
Попробуйте после записи сделать "Сообщить(НоваяНоменклатура.Код);"
И откройте заново номенклатуру с указанным номером. должно работать.
Возможно вы открываете не ту номенклатуру ?

[AlexCruel]

Михаил Е,
Та же карточка. Сейчас попробую разобраться с обязательными полями. Похоже, через код принудительно создается номенклатура без заполнения обязательных полей.

[AlexCruel]

Михаил Е, сделал тест на созданной номенклатуре - в большинстве своем поле доп. реквизита становится пустым, хотя эти значения есть в этом типе....
В тип "Строка" записывает изменения. Значит, проблема с типом значения "Дополнительные значения" и "Число". Можете подсказать на этот счет?

[Михаил Е]

AlexCruel Ну, с числом то в общемто всё то же самое, что и с строкой... (возможно какие-то ошибки не позволяют записать изменения?
а про "Дополнительные значения" - они хранятся в справочнике "ЗначенияСвойствОбъектов" с ссылкой на владельца (Там Владелец будет вашРеквизит). Можно попробовать или запросом, или

//ВашДополнительныйРеквизит = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоНаименованию("Предполагаемый срок эксплуатации");
МассивДополнительныхЗначений = УправлениеСвойствами.ПолучитьСписокЗначенийСвойств(ВашДополнительныйРеквизит);

А оттуда уже выбрать подходящее