Как в таблице вывести минуса?

Question

[Руслан Кириченко]

Здравствуйте ребята кто хорошо шарит в excel? Как в таблице вывести минуса?
Есть таблица товаров там есть цены, в плюсе и в минусе - вот надо как раз все минуса вывести на отдельный лист. Хорошо что если 1 лист и 5 строк вырезал и перенес на отдельный лист, а если 100 листов по 200 строк - не будешь же каждую строку вырезать? Помогите плизз...В excel я полный нуб вот решил его изучить.

Вот пример на фото: Где красные - это цены со знаком минус. Вот как раз их и надо вынести.

Answer 1

[Пычев Анатолий]

Включить Фильтр.
Отфильтровать по отрицательным значениям в нужном столбце.
Выделить все (Ctrl-A), скопировать и вставить на нужный лист
Повторить для всех листов

Либо писать макрос если это задача периодическая

Comments

[Руслан Кириченко]

Спасибо! Буду пробовать!

[h8nor]

В макросах функция Sgn возвращает единицу со знаком числа.

Answer 2

[nektopme]

Option Explicit


Sub Строки_на_Лист()
    ' не торопясь

    Dim wbk As Workbook: Set wbk = ActiveWorkbook
    Dim wsh_Temp As Worksheet
    Set wsh_Temp = wbk.Worksheets.Add(after:=Worksheets(Worksheets.Count))

    Dim wsh As Worksheet, cel As Range

    For Each wsh In wbk.Worksheets
        If wsh.Name <> wsh_Temp.Name Then
            For Each cel In Application.Intersect(wsh.UsedRange, wsh.Columns(6).Cells)
                If cel.Value < 0 Then
                    cel.EntireRow.Copy wsh_Temp.Cells(Row_Bottom_Number(wsh_Temp) + 1, 1)
                End If
            Next
        End If
    Next

End Sub


Function Row_Bottom_Number(ws As Worksheet) As Long
    ' Найти последнюю строку с данными, непустую

    Dim r As Range
    Set r = ws.Cells.Find(what:="*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious)

    If r Is Nothing Then
        Row_Bottom_Number = 1
    Else
        Row_Bottom_Number = r.Row
    End If
End Function