Delphi Async Callable?

Question

[Игорь]

Коллеги, приветствую.

Интересует вопрос, вызова асинхронных функций в Delphi.

На первом этапе создал следующий юнит

unit TD.AsyncFunc;

interface
 uses
  System.classes;

type
   TAsyncCallProc = reference to procedure;

type
 TAsyncFuncThread = class(TThread)
 private
    Fproc: TAsyncCallProc;
   { private declarations }
 protected
    procedure Execute; override;
 public
   constructor Create(const proc: TAsyncCallProc);


 published
   { published declarations }
 end;


procedure AsyncCallProc(const proc: TAsyncCallProc);

implementation

procedure AsyncCallProc(const proc: TAsyncCallProc);
var
 th: TAsyncFuncThread;
begin
 th:= TAsyncFuncThread.Create(proc)
end;

{ TAsyncFuncThread }

constructor TAsyncFuncThread.Create(const proc: TAsyncCallProc);
begin
  Fproc := proc;
  FreeOnTerminate := true;
  inherited Create(false);
end;

procedure TAsyncFuncThread.Execute;
begin
  Fproc;
end;

end.

Та тут и коню понятно, что этот способ не потоко-безопасный

Использовать так:

procedure TMainForm.Button3Click(Sender: TObject);
begin

  AsyncCallProc(
    procedure
    begin
      (Sender as TButton).Text := 'Начал выполнение';
      Sleep(5000);
      (Sender as TButton).Text := 'Закончил выполнение';
    end);

end;

Answer 1

[zed]

А в чём, собственно, вопрос? Чтобы сделать код потокобезопасным, обращение к гую надо завернуть в Synchronize метод (вызов Sleep, естественно, заворачивать не надо).
Вот туториал про использование TTask и синхронизацию: Using Tasks from the Parallel Programming Library

Comments

[Игорь]

Основная идея, иметь набор методов, которые можно использовать вот так:

procedure TMainForm.Button3Click(Sender: TObject);
begin

  AsyncCallProc(
    procedure
    begin
      (Sender as TButton).Text := 'Начал выполнение';
      Sleep(5000);
      (Sender as TButton).Text := 'Закончил выполнение';
    end);

end;

Я не могу (Sender as TButton).Text := завернуть в synchronize.

[zed]

Игорь, Разве вот так не сработает?

TTask.Run(
    procedure
    begin
           TThread.Synchronize(nil,
            procedure
            begin
                  (Sender as TButton).Text := 'Начал выполнение';
            end);

           Sleep(5000);

           TThread.Synchronize(nil,
            procedure
            begin
                  (Sender as TButton).Text := 'Закончил выполнение';
            end);
    end
);

[Игорь]

Простите, был не внимателен.
Synchronize можно засунуть

procedure TMainForm.Button3Click(Sender: TObject);
var
  promise: TPromise;
begin
  promise := AsyncCallProc(
    procedure
    var
      rand: integer;
    begin
      TThread.Synchronize(nil,
        procedure
        begin
          (Sender as TButton).Text := 'Начал выполнение';
        end);
      Sleep(1000);
      rand := Random(2);

      case rand of
        0:
          begin
          end;
        1:
          begin
            raise Exception.Create('My Exception')
          end;
      end;

      TThread.Synchronize(nil,
        procedure
        begin
          (Sender as TButton).Text := 'Закончил выполнение';
        end);

    end);

  promise.Resolve := Resolve;
  promise.Reject := Reject;
end;

[Игорь]

zedxxx, Да, ок. Работает.

Answer 2

[Hemul GM]

Если хочешь синхронизировать потоки из метода, то используй
TThread.Synchronize(<method>);