Как переформатировать время в имени файла конфига на микротике из 00:00:00 в 00-00-00?

Question

[Nik]

Пишу скрипт на микротике для автоматического сохранения backup-а на FTP сервер.
Нашел в интернете скрипт. Выглядит вот так:

log info "Starting Automatic Backup Script"
:global thisdate [/system clock get date]
:global time [/system clock get time]
:global datetimestring ([:pick $thisdate 0 3] ."-" . [:pick $thisdate 4 6] ."-" . [:pick $thisdate 7 11])
:global backupfilename ([/system identity get name]."_".$datetimestring."_$time")
:local ftpusername "mikrotik"
:local ftpuserpassword "Aa1234567"
:local ftphostname "10.7.8.120"
/system backup save name="$backupfilename"
:delay 5s
/export compact file="$backupfilename"
:log info "Please wait…!!!"
:delay 5s
:log info "Sending Backup Mikrotik to FTP Server…………."
/tool fetch address="$ftphostname" src-path="$backupfilename.backup" user="$ftpusername" password="$ftpuserpassword" port=21 upload=yes mode=ftp dst-path="$backupfilename.backup"
:delay 1
/tool fetch address="$ftphostname" src-path="$backupfilename.rsc" user="$ftpusername" password="$ftpuserpassword" port=21 upload=yes mode=ftp dst-path="$backupfilename.rsc"
:delay 1
/file remove "$backupfilename.backup"
/file remove "$backupfilename.rsc"
:log info "Finished Backup Script…!!!!"

Тут есть строка с переменной _$time

:global backupfilename ([/system identity get name]."_".$datetimestring."_$time")

Суть в том что эта переменная записывает его как 00:00:00, а винда не понимает такой формат файла, тупо не допускает в имени файла символы :, как мне преобразовать эти символы в -, чтобы винда позволила мне сохранить конфиг на FTP?

Answer 1

[Станислав Валсинатс]

Можно я попробую.

Сам не писал скрипты для микротика, но писал для других систем. Давайте посмотрим на строки:

1) :global thisdate [/system clock get date]
2) :global time [/system clock get time]
3) :global datetimestring ([:pick $thisdate 0 3] ."-" . [:pick $thisdate 4 6] ."-" . [:pick $thisdate 7 11])

1) Мы получаем дату и запихиваем ее в переменную в каком то виде
2) В переменную time мы просто запихиваем время в каком то виде
3) В переменную datetimestring мы ФОРМАТИРУЕМ и запихиваем дату в нужном нам виде.

Следовательно, нам нужно то же самое проделать и со временем. Что бы сделал Я =)

1) Создал переменную по типу:
:global timestring
2) обработал бы правилом, как указал товарищ выше - ([:pick $thisdate 0 3] ."-" . [:pick $thisdate 4 6] ."-" . [:pick $thisdate 7 11])

Если pick - это вырез подстроки заданного диапазона из переменной (thisdate ), то можно понять что с начала вырезается с 0 по 3 символ, объединяется с символом " - " , дальше с 4 по 6 символ из переменной , потом объединяем его с " - " , и потом берем последнюю часть с 7 по 11 символ и объединяем его с " - ".

Вроде пока понятно ??

ТОгда, ПО ВАШИМ словам , если переменная time выдает 00:00:00, где допустим ЧЧ.ММ.СС впрочем не важно, то для модификации вам надо добавить строку после time

:global timestring ([:pick $thisdate 0 1] ."-" . [:pick $thisdate 3 4] ."-" . [:pick $thisdate 6 7])

И далее поправить строку формирования имени выходного файла :

Было так -
:global backupfilename ([/system identity get name]."_".$datetimestring."_$time")

Станет так -
:global backupfilename ([/system identity get name]."_".$datetimestring."_$timestring ")

Попробуйте

Comments

[20ivs]

понятней объяснить невозможно =)

[Nik]

Заработало!!! Спасибище тебе большое. На будущее коллегам выкладываю скрипт.

:log info "Starting Automatic Backup Script"
:global thisdate [/system clock get date]
:global datetimestring ([:pick $thisdate 0 3] ."-" . [:pick $thisdate 4 6] ."-" . [:pick $thisdate 7 11])
:global thistime [/system clock get time]
:global timestring ([:pick $thistime 0 2] ."-" . [:pick $thistime 3 5] ."-" . [:pick $thistime 6 8])
:global backupfilename ([/system identity get name]."_".$datetimestring."_".$timestring)
:local ftpusername "username"
:local ftpuserpassword "password"
:local ftphostname "IPADDR"
/system backup save name="$backupfilename"
:delay 5s
/export compact file="$backupfilename"
:log info "Please wait!!!"
:delay 5s
:log info "Sending Backup Mikrotik to FTP Server."
/tool fetch address="$ftphostname" src-path="$backupfilename.backup" user="$ftpusername" password="$ftpuserpassword" port=21 upload=yes mode=ftp dst-path="/xx/xx/$backupfilename.backup"
:delay 3s
/tool fetch address="$ftphostname" src-path="$backupfilename.rsc" user="$ftpusername" password="$ftpuserpassword" port=21 upload=yes mode=ftp dst-path="/xx/xx/$backupfilename.rsc"
:delay 3s
/file remove "$backupfilename.backup"
/file remove "$backupfilename.rsc"
:log info "Finished Backup Script!!!!"

[fitbikeco]

как вариант

:local time ([:pick [system clock get time] 0 2]."-".[:pick [system clock get time] 3 5]."-".[:pick [system clock get time] 6 8]);
:local date ([:pick [/system clock get date] 7 11] . [:pick [/system clock get date] 0 3] . [:pick [/system clock get date] 4 6]);
:local vROS [system routerboard get current-firmware ];
:local DevName [:pick [system identity get] [:find "=" ] ];
/system backup save dont-encrypt=yes name="/$date\_$time\_$vROS\_backup\_$DevName";
/export file="/$date\_$time\_$vROS\_export\_full\_$DevName";
/system export file="/$date\_$time\_$vROS\_export\_system\_$DevName";
/tool export file="/$date\_$time\_$vROS\_export\_tool\_$DevName";
/interface export file="/$date\_$time\_$vROS\_export\_interface\_$DevName";
/ip export file="/$date\_$time\_$vROS\_export\_ip\_$DevName";
/ipv6 export file="/$date\_$time\_$vROS\_export\_ipv6\_$DevName";

одной строкой для теста в терминале

:local time ([:pick [system clock get time] 0 2]."-".[:pick [system clock get time] 3 5]."-".[:pick [system clock get time] 6 8]);:local date ([:pick [/system clock get date] 7 11] . [:pick [/system clock get date] 0 3] . [:pick [/system clock get date] 4 6]);:local vROS [system routerboard get current-firmware ];:local DevName [:pick [system identity get] [:find "=" ] ];/system backup save dont-encrypt=yes name="/$date\_$time\_$vROS\_backup\_$DevName";/export file="/$date\_$time\_$vROS\_export\_full\_$DevName";/system export file="/$date\_$time\_$vROS\_export\_system\_$DevName";/tool export file="/$date\_$time\_$vROS\_export\_tool\_$DevName";/interface export file="/$date\_$time\_$vROS\_export\_interface\_$DevName";/ip export file="/$date\_$time\_$vROS\_export\_ip\_$DevName";/ipv6 export file="/$date\_$time\_$vROS\_export\_ipv6\_$DevName";

проверено на RouterOS 7.1.1 и
6.49.2

Answer 2

[Moskus]

Сами сможете переписать и применить эту функцию для ваших нужд?

:global replaceChar do={
  :for i from=0 to=([:len $1] - 1) do={
    :local char [:pick $1 $i]
    :if ($char = $2) do={
      :set $char $3
    }
    :set $output ($output . $char)
  }
  :return $output
}

Comments

[Nik]

Это код надо применить после
:global backupfilename ([/system identity get name]."_".$datetimestring."_$time")
Правильно?

[Moskus]

Nik, вы совсем не умеете программировать?

[Nik]

Moskus, Нет. Я не программист))

[Moskus]

Nik, с этого надо начинать.

[fitbikeco]

примерно так
{
:local 1 (":") ;
:local 2 ("-") ;
:local output ;
:local time ([/system clock get time]);
  :for i from=0 to=([:len $time] - 1) do={
    :local char [:pick $time $i] ;
    :if ($char = $1) do={
      :set $char $2 ;
    } ;
    :set $output ($output . $char)
  } ;
  :return $output ;
};

одной строкой для теста в терминале

{:local 1 (":") ;:local 2 ("-") ;:local output ;:local time ([/system clock get time]); :for i from=0 to=([:len $time] - 1) do={ :local char [:pick $time $i] ; :if ($char = $1) do={ :set $char $2 ; } ; :set $output ($output . $char) } ; :return $output ;};

global - лишняя нагрузка на cpu
if - лишняя нагрузка на cpu

можно так

:local time ([:pick [system clock get time] 0 2]."-".[:pick [system clock get time] 3 5]."-".[:pick [system clock get time] 6 8]); :put $time

протестировано на RouterOS 7.1.1

Answer 3

[Дмитрий Шицков]

:global datetimestring ([:pick $thisdate 0 3] ."-" . [:pick $thisdate 4 6] ."-" . [:pick $thisdate 7 11])

Аналогично поступите с переменной со временем. Как здесь, разбивайте на более мелкие части дату(время) и подставляйте "-" где нужно

Comments

[Nik]

А за что эта строка отвечает?

[Дмитрий Шицков]

Nik, Эээ, очивидно, что за формирование строки даты-времени

[Nik]

Дмитрий Шицков, Просто мне не понятно, зачем 0 3, 4 6, 7 11???
И все таки как вышеописанный скрипт применить?

[Дмитрий Шицков]

Nik, прочтите уже документацию по Микротик.
нужно модифицировать строку со временем. Это пример модификации строки даты.
pick вырезает из строки подстроки в указанном диапазоне для последующей склейки через правильный символ.

[Nik]

Дмитрий Шицков, Все таки я не понял как это сделать.