WIA ошибка при установке параметра PAGES (VBA). Почему?

Question

[KTG]

Sub scan()
    Dim objDM As WIA.DeviceManager
    
        Dim objDev As WIA.Device
        
            Dim objItem As WIA.Item
            Dim objImage As WIA.ImageFile
        
        Dim s As String
        Dim i As Integer
        
        Dim p As Property
       
     Set objDM = New WIA.DeviceManager
     For i = 1 To objDM.DeviceInfos.Count
        If objDM.DeviceInfos(i).Type = 1 Then
          s = objDM.DeviceInfos(i).DeviceID
        End If
     Next
     
     Set objDev = objDM.DeviceInfos(s).Connect
     If objDev Is Nothing Then
        MsgBox ("Error: Not device found")
     Else
        objDev.Properties("Document Handling Select").Value = 1
        objDev.Properties("Pages").Value = 1
        
            Set objItem = objDev.Items(1)
            Set objImage = objItem.Transfer(WIA.FormatID.wiaFormatTIFF)
'            objImage.SaveFile "c:\test\" & ActiveCell.Value & ".TIFF"
            
        Set objItem = Nothing
        Set objImage = Nothing
        Set objDev = Nothing
     End If
     
     Set objDev = Nothing
     Set objDM = Nothing
    
End Sub

На сколько я разобрался, то строка

objDev.Properties("Document Handling Select").Value = 1

отвечает за то, откуда берется бумага и какой тип сканирования. , В данном случае бумагу меня хватает с лотка автоподачи.

Эта же строчка отвечает за количество отсканируемых страниц из лотка.
objDev.Properties("Pages").Value = 1
Если поставить 0, то должен сканировать автоматом все, которые лежат в лотке.
Если 1 - то только 1 лист.

Так вот. Почему-то, при изменении количества страниц
например: objDev.Properties("Pages").Value = 0
Выдает ошибку о неверно заданном параметре и в Debug подсвечитвает следующую строку:

Set objImage = objItem.Transfer(WIA.FormatID.wiaFormatTIFF)

Как быть?
У меня не получается определять наличие бумаги в автоподатчике.
Хотя по идее МФУ это предусматривает, по крайне мере при попытке сканировать и не закладывая бумагу - он об этом сообщает.
Как крайний вариант, оставил себе в запасе решение в цикле, до выхода ошибки OnError.
Но мне кажется, это не совсем правильно.

И да. Почему-то в VBA не работают контстанты, WIA_DPS_PAGES например.

Comments

[h8nor]

На С-ях так и пишут 'try', так что лучше сразу добавить отлов исключений. Причём проверка нужна даже на этапе If objDM.DeviceInfos.Count < 1 Then Exit Sub т.к. в WinXP этого драйвера нет (прописывал 5.1.2600.1106) или сканер может быть не включён в сеть. Статьи по драйверу.

[h8nor]

Есть одна идея. Интересно, какие параметры выводит сканер с автоподачтиком?

Sub Test_p3088_and_p3096()
  Dim CommonDialog1 As New CommonDialog
  Dim dev 'As Device
  Dim p 'As Property
  Dim s As String
  Dim i As Integer
  
  Set dev = CommonDialog1.ShowSelectDevice
  For Each p In dev.Properties
    If p.PropertyID = 3087 Or p.PropertyID = 3088 Or p.PropertyID = 3096 Then
      s = s & p.Name & "(" & p.PropertyID & ") = " & p.Value
      If p.SubType <> UnspecifiedSubType Then
        If p.Value <> p.SubTypeDefault Then
          s = s & "(Default = " & p.SubTypeDefault & ")"
        End If
      End If
      Select Case p.SubType
        Case FlagSubType
          s = s & " [ valid flags include:"
          For i = 1 To p.SubTypeValues.Count
            s = s & p.SubTypeValues(i)
            If i <> p.SubTypeValues.Count Then s = s & ", "
          Next i
          s = s & " ]"
        Case RangeSubType
          s = s & " [ valid values in the range from " & _
            p.SubTypeMin & " to " & p.SubTypeMax & _
            " in increments of " & p.SubTypeStep & " ]"
      End Select
      s = s & vbCr
    End If
  Next p
  Debug.Print s
End Sub

Значения на бюджетном МФУ:

Document Handling Select(3088) = 2 [ valid flags include:2 ]
Pages(3096) = 1 [ valid values in the range from 0 to 100 in increments of 1 ]
Document Handling Status(3087) = 2(Default = 12354) [ valid flags include: ]

[KTG]

Document Handling Select и Status = 3. Pages по умолчанию 1.

[KTG]

Забыл упоямнуть. Мне показалось "адовым" приписки в MSDN к WIA на те или иные параметры, в том числе Handling Status, Select, Pages, где они есть в свойствах сканера DPS, и в свойствах изображения IPS и куча приписок применяемыми ими параметров, которые работают, то только в XP, то только в WIN 7, то в Vista и выше и т.д.

Answer 1

[KTG]

Вот кстати полностью рабочий код, который делает то, что от него требуется.
Сканирует без диалога все листы из автоподатчика, пока не вывалиться ошибка Err.Number -2145320957.
Затем все конвертирует в TIFF и сохраняет в один многостраничный документ.

Sub scan()
    
    Dim objDM As WIA.DeviceManager
    'MsgBox (Split(ActiveCell.Address, "$")(1))
        Dim objDev As WIA.Device
        
            Dim objItem As WIA.Item
            Dim objImage, FirstImage As WIA.ImageFile
            Dim objIP As WIA.ImageProcess
        
        Dim s As String
        Dim i, num As Integer
      
     Set objDM = New WIA.DeviceManager
     For i = 1 To objDM.DeviceInfos.Count
        If objDM.DeviceInfos(i).Type = 1 Then
          s = objDM.DeviceInfos(i).DeviceID
        End If
     Next
     
     Set objDev = objDM.DeviceInfos(s).Connect
     If objDev Is Nothing Then
        MsgBox ("Error: Not device found")
     Else

        objDev.Properties("Document Handling Select").Value = 1
        objDev.Properties("Pages").Value = 1
     
        Set objItem = objDev.Items(1)
     
            Set objImage = New WIA.ImageFile
            Set objIP = New WIA.ImageProcess
            
ScanStart:

        On Error GoTo ScanError
            
            Set objImage = objItem.Transfer("{B96B3CB1-0728-11D3-9D7B-0000F81EF32E}")
            num = num + 1
            If num = 1 Then
                Set FirstImage = objImage
            Else
                objIP.Filters.Add (objIP.FilterInfos("Frame").FilterID)
                objIP.Filters(objIP.Filters.Count).Properties("ImageFile") = objImage
                objIP.Filters(objIP.Filters.Count).Properties("FrameIndex") = objIP.Filters.Count
            End If

        GoTo ScanStart
        
ScanError:

        Select Case Err.Number
            Case -2145320957
                MsgBox ("No More Pages Found")

                objIP.Filters.Add (objIP.FilterInfos("Convert").FilterID)
                objIP.Filters(objIP.Filters.Count).Properties("FormatID") = "{B96B3CB1-0728-11D3-9D7B-0000F81EF32E}"
                Set FirstImage = objIP.Apply(FirstImage)
                FirstImage.SaveFile "c:\test\" & ActiveCell.Value & num & ".TIFF"
            Case Else
                MsgBox ("Error: " & Err.Description & "(" & Err.Number & ")")
        End Select
        
        Set FirstImage = Nothing
        Set objItem = Nothing
        Set objImage = Nothing
        Set objDev = Nothing
     End If
     
     Set objDev = Nothing
     Set objDM = Nothing
    
End Sub

Comments

[KTG]

ну и поясню, что TIFF он делает путем применения фильтров к первой картинке.
Долго мучался по примеру из msdn, пока не додумался вручную проставлять FrameIndex. Без этого работать не хотел.
И да, конвертировать то же обязательно, т.к. формат файла должен поддерживать ту самую многостраничность. По умолчанию сканирует в .bmp

[KTG]

KTG: исправляюсь. FrameIndex проставлять не обязательно. Видимо все же дело было в конвертации. А ручное прописывание индекса вносило сумятицу в очередность страниц.

[h8nor]

Красавчик! Если требуются замечания:

1. Всё же лучше добавить проверку

   If objDM.DeviceInfos.Count < 1 Then MsgBox "The scanner is not connected": Exit Sub

2. У меня МФУ сканирует только в BMP (смотрел в отладчике), поэтому свойство работает как Set objImage = objItem.Transfer.

[vasyatky]

А к чему отнести ActiveCell.Value?!....да и в один tiff изображения не соединяются