Сбор бэкапов микротик?

Question

[MrDZ]

Задача собирать раз в месяц с микротиков бэкап (при этом сохранять на самом микротике тоже). Как вы у себя данную процедуру делаете. И может ссылки накидаете, с помощью которых настраивали у себя.
unix машины не использую.

Answer 1

[Никита Сизов]

Отправляю на FTP-сервер по расписанию через tools/fetch

Comments

[MrDZ]

скриптом поделишься?

[Никита Сизов]

MrDZ,

{
:local date ([:pick [/system clock get date] 4 6] . [:pick [/system clock get date] 0 3] . [:pick [/system clock get date] 7 11]);
:local backupfile ([/system identity get name] . "-" . $date);
#ftp account
:local ftphost "10.12.149.2";
:local ftpuser "ftpaccess";
:local ftppassword "secretpassword";
:local ftppath "/confbackup/mikrotik";

#create full system backup files
/system backup save name="$backupfile.backup";
:delay 10s;

#create config export files
/export file="$backupfile.rsc";
:delay 10s;

# upload the system backup
:log info message="Uploading system backup"
/tool fetch address="$ftphost" src-path="$backupfile.backup" user="$ftpuser" mode=ftp password="$ftppassword" dst-path="$ftppath/$backupfile.backup" upload=yes
:delay 30s;

# upload the config export
:log info message="Uploading config export"
/tool fetch address="$ftphost" src-path="$backupfile.rsc" user="$ftpuser" mode=ftp password="$ftppassword" dst-path="$ftppath/$backupfile.rsc" upload=yes
:delay 30s;

# find file name $backupfile- then remove
/file remove [find name~".backup"];
/file remove [find name~".rsc"];
#:foreach i in=[/file find] do={ :if ([:typeof [:find [/file get $i name] "$backupfile"]]!="nil") do={/file remove $i}; }
:log info message="Configuration backup finished";
}

[MrDZ]

Никита Сизов, благодарствую

Answer 2

[Дмитрий Шицков]

1. Описанный в вики способ с отправкой бекапа по email
   
2. Через scp/ssh https://wiki.mikrotik.com/wiki/Using_SSH_for_syste... Для Windows: plink, pscp