Как получается элемент списка?

Question

[taaadm]

Вот прога с сайта Zabbix:

#!/usr/bin/perl
 
$first = 1;
 
print "{\n";
print "\t\"data\":[\n\n";
 
for (`cat /proc/mounts`)
{
    ($fsname, $fstype) = m/\S+ (\S+) (\S+)/;
    $fsname =~ s!/!\\/!g;
 
    print "\t,\n" if not $first;
    $first = 0;
 
    print "\t{\n";
    print "\t\t\"{#FSNAME}\":\"$fsname\",\n";
    print "\t\t\"{#FSTYPE}\":\"$fstype\"\n";
    print "\t}\n";
}
 
print "\n\t]\n";
print "}\n";

Цикл по полученному списку (`cat /proc/mounts`). Но как тут получается элемент списка? Где какое ни будь присваивание, на пример? Объясните пожалуйста

Answer 1

[krypt3r]

Вот присваивание:
($fsname, $fstype) = m/\S+ (\S+) (\S+)/;
ЗЫ. Сплошной гoвнoкoд. Лучше что-то типа

#!/usr/bin/perl

use strict;
use warnings;
use JSON;
 
open my $F, '<', '/proc/mounts' or die "open() error: $!\n";
my ($fsname, $fstype, %result);
while (<$F>)
{
    ($fsname, $fstype) = (split /\s+/)[1, 2];
    #$fsname =~ s!/!\\/!g;
    push @{$result{'data'}}, {'{#FSNAME}' => $fsname, '{#FSTYPE}' => $fstype};
}
close $F;
print JSON->new->pretty->encode (\%result);

Comments

[taaadm]

Объясните пожалуйста по подробнее как это присваивание работает?

[taaadm]

Или как мне например получить всю строку целиком?

[krypt3r]

Файл /proc/mounts обрабатывается построчно, внутри цикла каждая строка записывается в переменную $_. Далее эта переменная обрабатывается регуляркой m/\S+ (\S+) (\S+)/, берутся первые три элемента строки, разделенные пробелом (\S+ один или более непробельный символ). "Захватываются" второй и третий элемент строки, что показывают круглые скобки (\S+). Вот эти элементы и попадают в переменные $fsname и $fstype. Вариант этот фиговый, мой со split() лучше.
А вообще, зачем вам это всё?

[taaadm]

а как мне получить всю строку целиком?Хочу разобраться в этом варианте и адаптировать скрипт под свои нужды. Сейчас сделал с foreach $i (`cat /proc/mounts`), так понятнее.

[krypt3r]

Я же вам написал "внутри цикла каждая строка записывается в переменную $_". Это встроенная переменная перла и во многих случаях ее можно опускать. Посмотрите в мой пример, там строка split /\s+/, которую можно переписать как split (/\s+/, $_). Круглые скобки тут необязательны, но пусть будут

Answer 2

[pcdesign]

В этой строке происходит присваивание:
($fsname, $fstype) = m/\S+ (\S+) (\S+)/;

Переменной $fsname присваивается $1, а переменной $fstype присваивается $2.
Если вы спросите, что такое $1, а что такое $2?
То это результат того, что было найдено в регулярном выражении.
Первые круглые скобки - это $1.
Вторые круглые скобки - это $2.

Comments

[taaadm]

Я не видел, что подается на вход этого регулярного выражения. krypt3r уже объяснил про встроенную переменную $_, которую можно опустить

[taaadm]

Кстати как сказал krypt3r, в выражении split (/\s+/, $_) если опустить $_ выражение выглядит split /\s+/, а как будет выглядеть выражение m/\S+ (\S+) (\S+)/ в этом случае?

[pcdesign]

taaadm: мда.

[krypt3r]

taaadm: Можно написать в несколько строк

$_ =~ m/\S+ (\S+) (\S+)/;
$fsname = $1;
$fstype = $2;

Answer 3

[dionys]

Операция `` возвращает список строк. В цикле for каждая строка неявно попадает в специальную переменную $_. Следующая операция m// также неявно работает с этой переменной. В явном виде цикл будет выглядеть так:

for my $_ (`cat /proc/mounts`) {
    ($fsname, $fstype) = $_ =~ m/\S+ (\S+) (\S+)/;
    ...
}