Почему запрос формируется бесконечно долго?

Question

[fuad99377]

Запрос формируется бесконечно. Результат никак не могу увидеть. В чем может быть проблема?

ВЫБРАТЬ
	ЕСТЬNULL(СУММА(ВЫБОР
				КОГДА ВТ_БИ.ЭтоВалютныйСчет
					ТОГДА ВТ_БИ.ВалютнаяСуммаНачальныйОстаток
				ИНАЧЕ ВТ_БИ.СуммаНачальныйОстаток
			КОНЕЦ), 0) КАК НачальныйОстаток,
	ЕСТЬNULL(СУММА(ВЫБОР
				КОГДА ВТ_БИ.ЭтоВалютныйСчет
					ТОГДА ВТ_БИ.ВалютнаяСуммаОборотДт
				ИНАЧЕ ВТ_БИ.СуммаОборотДт
			КОНЕЦ), 0) КАК ВсегоПоступило,
	ЕСТЬNULL(СУММА(ВЫБОР
				КОГДА ВТ_БИ.ЭтоВалютныйСчет
					ТОГДА ВТ_БИ.ВалютнаяСуммаОборотКт
				ИНАЧЕ ВТ_БИ.СуммаОборотКт
			КОНЕЦ), 0) КАК ВсегоСписано,
	ЕСТЬNULL(СУММА(ВЫБОР
				КОГДА ВТ_БИ.ЭтоВалютныйСчет
					ТОГДА ВТ_БИ.ВалютнаяСуммаКонечныйОстаток
				ИНАЧЕ ВТ_БИ.СуммаКонечныйОстаток
			КОНЕЦ), 0) КАК КонечныйОстаток
ИЗ
	(ВЫБРАТЬ
		БИ.СуммаНачальныйОстаток КАК СуммаНачальныйОстаток,
		БИ.ВалютнаяСуммаНачальныйОстаток КАК ВалютнаяСуммаНачальныйОстаток,
		БИ.СуммаОборотДт КАК СуммаОборотДт,
		БИ.ВалютнаяСуммаОборотДт КАК ВалютнаяСуммаОборотДт,
		БИ.СуммаОборотКт КАК СуммаОборотКт,
		БИ.ВалютнаяСуммаОборотКт КАК ВалютнаяСуммаОборотКт,
		БИ.СуммаКонечныйОстаток КАК СуммаКонечныйОстаток,
		БИ.ВалютнаяСуммаКонечныйОстаток КАК ВалютнаяСуммаКонечныйОстаток,
		ВЫБОР
			КОГДА БИ.ВалютнаяСуммаНачальныйОстаток <> 0
					ИЛИ БИ.ВалютнаяСуммаОборотДт <> 0
					ИЛИ БИ.ВалютнаяСуммаОборотКт <> 0
					ИЛИ БИ.ВалютнаяСуммаКонечныйОстаток <> 0
				ТОГДА ИСТИНА
			ИНАЧЕ ЛОЖЬ
		КОНЕЦ КАК ЭтоВалютныйСчет
	ИЗ
		РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(&ДатаИтоговНачалоДня, &ДатаИтоговКонецДня, , ДвиженияИГраницыПериода, Счет В (&СчетаССубконтоБанковскиеСчета), &ВидСубконтоБанковскиеСчета, Организация В (&Организации) {(ВЫРАЗИТЬ(Субконто1 КАК Справочник.БанковскиеСчета)) КАК БанковскийСчетИтогов}) КАК БИ) КАК ВТ_БИ

Пробовал логику этого же запроса и без вложенного запроса. Еще пробовал вместо ЭтоВалютныйСчет во вложенном запросе просто ставить условие, пример одного поля

ВЫБОР
    КОГДА ХозрасчетныйОстаткиИОбороты.ВалютнаяСуммаНачальныйОстаток <> 0
    ТОГДА ХозрасчетныйОстаткиИОбороты.ВалютнаяСуммаНачальныйОстаток
    ИНАЧЕ ХозрасчетныйОстаткиИОбороты.СуммаНачальныйОстаток
КОНЕЦ

Но все одно и то же. Параметр ВидыСубконтоХозрасчетные = БанковскиеСчета, параметры ДатаИтоговКонецДня и ДатаИтоговНачалоДня - это даты одного дня (08.01.2021 23:59:59 и 08.01.2021 00:00:00 соответственно)

Answer 1

[Дмитрий Кинаш]

Чтобы запросы выполнялись быстро, запросы должны быть понятными! Только для понятных запросов планировщик сможет создать план выполнения с максимальной эффективностью!

А что тут у вас???

1) Зачем тут вложенный запрос? Мало того, что он не имеет смысла, так он еще заставляет выделять в два раза больше памяти на стороне СУБД чем нужно. Удалить!

2) Зачем тут ЕСТЬNULL ? Эта функция для подстановки значений по умолчанию при соединениях (когда под условие соединения не попадают некоторые поля) или при обращении к реквизитам ссылки (когда ссылка может быть пустой). Тут нет ни первого ни второго случая. СУБД пытается понять что от нее хотят и делает ряд вспомогательных таблиц в памяти, которых вообще не должно было быть!

3) Почему в запросе 4 поля с функцией СУММА и ни одного группировочного? Это вообще не имеет смысла. Тем более, что виртуальная таблица РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты сама суммирует суммовые показатели по выбранным счетам/измерениям.

4) Почему каждое выбираемое поле обвернуто в условный оператор ВЫБОР? Это вообще не позволяет выполнять никаких оптимизаций.

Как это можно оптимизировать?

1) Запрос должен быть единым - без вложенных подзапросов и временных таблиц!

2) Вместо бредятины с анализом входящего и исходящего валютного сальдо нужно использовать признак валютности в счете (имею в виду бухгалтерский счет, а не мультивалютность в банковском счете). Различные валютные переоценки валютных счетов проходят только корректировкой балансовых сумм и с нулями по валютной сумме - в логике текущего запроса такие валютные счета будут считаться невалютными.

3) Сделать группировку суммовых полей (обычных и валютных) по признаку валютности - в результате получим не одну строчку, а две, но которые легко проанализировать в коде. В крайнем случае, если критически важно в результате выполнения запроса получить только одну строку, то можно нарушить совет №1 и сделать временную таблицу, чтобы потом во втором запросе уже за микросекунды соединить две строки в одну единую.

Comments

[fuad99377]

Здравствуйте Дмитрий, я понял указанные вами ошибки. Переделал запрос вот так

ВЫБРАТЬ
	СУММА(ХозрасчетныйОстаткиИОбороты.ВалютнаяСуммаНачальныйОстаток) КАК НачальныйОстатокВалютный,
	СУММА(ХозрасчетныйОстаткиИОбороты.ВалютнаяСуммаОборотДт) КАК ВсегоПоступилоВалютный,
	СУММА(ХозрасчетныйОстаткиИОбороты.ВалютнаяСуммаОборотКт) КАК ВсегоСписаноВалютный,
	СУММА(ХозрасчетныйОстаткиИОбороты.ВалютнаяСуммаКонечныйОстаток) КАК КонечныйОстатокВалютный,
	ХозрасчетныйОстаткиИОбороты.Счет.Валютный КАК СчетВалютный,
	СУММА(ХозрасчетныйОстаткиИОбороты.СуммаНачальныйОстаток) КАК НачальныйОстаток,
	СУММА(ХозрасчетныйОстаткиИОбороты.СуммаОборотДт) КАК ВсегоПоступило,
	СУММА(ХозрасчетныйОстаткиИОбороты.СуммаОборотКт) КАК ВсегоСписано,
	СУММА(ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстаток) КАК КонечныйОстаток
ИЗ
	РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(&ДатаИтоговНачалоДня, &ДатаИтоговКонецДня, , ДвиженияИГраницыПериода, Счет В (&СчетаССубконтоБанковскиеСчета), &ВидСубконтоБанковскиеСчета, Организация В (&Организации)) КАК ХозрасчетныйОстаткиИОбороты

СГРУППИРОВАТЬ ПО
	ХозрасчетныйОстаткиИОбороты.Счет.Валютный

Но и этот ведет себя также, запрос выполняется бесконечно.

Потом попробовал что то подобное тому как вы указали

то можно нарушить совет №1 и сделать временную таблицу, чтобы потом во втором запросе уже за микросекунды соединить две строки в одну единую.

. Сделал так

ВЫБРАТЬ
	ХозрасчетныйОстаткиИОбороты.ВалютнаяСуммаНачальныйОстаток КАК НачальныйОстаток,
	ХозрасчетныйОстаткиИОбороты.ВалютнаяСуммаОборотДт КАК ВсегоПоступило,
	ХозрасчетныйОстаткиИОбороты.ВалютнаяСуммаОборотКт КАК ВсегоСписано,
	ХозрасчетныйОстаткиИОбороты.ВалютнаяСуммаКонечныйОстаток КАК КонечныйОстаток,
	ХозрасчетныйОстаткиИОбороты.Счет КАК Счет
ПОМЕСТИТЬ ВТ_Валютный
ИЗ
	РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(
			&ДатаИтоговНачалоДня,
			&ДатаИтоговКонецДня,
			,
			ДвиженияИГраницыПериода,
			Счет.Валютный = ИСТИНА
				И Счет В (&СчетаССубконтоБанковскиеСчета),
			&ВидСубконтоБанковскиеСчета,
			Организация В (&Организации)) КАК ХозрасчетныйОстаткиИОбороты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ХозрасчетныйОстаткиИОбороты.СуммаНачальныйОстаток КАК НачальныйОстаток,
	ХозрасчетныйОстаткиИОбороты.СуммаОборотДт КАК ВсегоПоступило,
	ХозрасчетныйОстаткиИОбороты.СуммаОборотКт КАК ВсегоСписано,
	ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстаток КАК КонечныйОстаток,
	ХозрасчетныйОстаткиИОбороты.Счет КАК Счет
ПОМЕСТИТЬ ВТ_НеВалютный
ИЗ
	РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(
			&ДатаИтоговНачалоДня,
			&ДатаИтоговКонецДня,
			,
			ДвиженияИГраницыПериода,
			Счет.Валютный = ЛОЖЬ
				И Счет В (&СчетаССубконтоБанковскиеСчета),
			&ВидСубконтоБанковскиеСчета,
			Организация В (&Организации)) КАК ХозрасчетныйОстаткиИОбороты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВТ_Валютный.НачальныйОстаток КАК НачальныйОстаток,
	ВТ_Валютный.ВсегоПоступило КАК ВсегоПоступило,
	ВТ_Валютный.ВсегоСписано КАК ВсегоСписано,
	ВТ_Валютный.КонечныйОстаток КАК КонечныйОстаток,
	ВТ_Валютный.Счет КАК Счет
ИЗ
	ВТ_Валютный КАК ВТ_Валютный

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
	ВТ_НеВалютный.НачальныйОстаток,
	ВТ_НеВалютный.ВсегоПоступило,
	ВТ_НеВалютный.ВсегоСписано,
	ВТ_НеВалютный.КонечныйОстаток,
	ВТ_НеВалютный.Счет
ИЗ
	ВТ_НеВалютный КАК ВТ_НеВалютный

Я понимаю что сделал не совсем так как вы указали. Я только учусь, прошу строго не судить (кстати, первый запрос указанный, вообще не мой запрос. Мне дали его "оптимизировать").

[Дмитрий Кинаш]

fuad99377, первый запрос норм. Продолжаем оптимизировать.

1) Если вам нужны начало и конец периода, то зачем вы делаете ДвиженияИГраницыПериода? Движения только мешают и тут уходит значительный процент времени на выбо того, что нам не нужно. Оставляйте только границы периода.

2) Зачем вы передаете список видов субконто? Тут тоже уходит очень много времени на анализ счетов и создание виртуальной таблицы в которой субконто будут в указанной вами последовательности. Смотрим пункт №1 - это выполняется для каждого движения периода! Убирийте этот параметр и оставляйте там пустоту.