Гугл формула игнорирует регистр, что делать?

Question

[Shigobik]

У меня стоит выделение текстом в таблице, по формуле (условное форматирование)
На совпадение с другим листом.
Выглядит это так.
=MATCH($D5;INDIRECT("Именованный_диапазон1");)
Проблема в том, что он подсвечивает слова с разным регистром.
Например "яблоко" и "Яблоко", для формулы это одно и то же...
Как это можно поправить, чтоб формула различала регистр?

Answer 1

[Григорий Боев]

Если данные не списочные, приводите их к одному виду.
СТРОЧН() для текста, можно ещё СЖПРОБЕЛЫ() применить (получаем чистый текст)
ОКРУГЛВНИЗ() для дат (получаем только дату, без времени)
+() для чисел, чтобы не-числа стали числами
и так далее

Comments

[Shigobik]

У меня списки на разных листах. Столбец А листа1 и Столбец В листа2
Столбец имен грубо говоря.
Мне надо, чтоб подсвечивало совпадения имен в колонке А, листа1.
=MATCH($D5;INDIRECT("Именованный_диапазон1");)
И эта формула работает, он посдвечивает, но не учитывает регистр. Если в одном листе имя с маленькой буквы, то он все равно его подсвечивает на другом листе...

[Григорий Боев]

Shigobik, попробуйте REGEXMATCH

[Shigobik]

Григорий Боев, Мне выше предлагали уже, я там ответил, что она не работает...

[Григорий Боев]

Ну тогда что-то вроде:

=REGEXMATCH($D5;JOIN("|"; INDIRECT("Именованный_диапазон1")))

[Shigobik]

Григорий Боев, что то он мне вообще весь диапазон цветом закрасил...

[Григорий Боев]

Всё работает
Отфильтруйте пустые строки во втором диапазоне

=REGEXMATCH($D5;JOIN("|"; FILTER(INDIRECT("Именованный_диапазон1"); INDIRECT("Именованный_диапазон1")<>"")))

Пример таблицы

[Shigobik]

Григорий Боев, сложная формула для меня... я вот не понимаю что это такое "|"
А к ней можно прикрутить условие или просто соотвтетсвие двум диапазонам?
Проще говоря ща формула работает по двум листам, сверяет и выделяет цветом.
Допустим есть 3 лист. Если имя есть в листе 2 и листе 3, то тогда выделяет цветом. Ну или если его нет в листе 3.
А так спасибо, большое)

[Григорий Боев]

Черта - это часть регулярного выражения, в таблице есть пример того что получается.

Это список нужных слов:

FILTER(INDIRECT("Именованный_диапазон1"); INDIRECT("Именованный_диапазон1")<>"")

Если надо расширить его - расширяйте:

VSTACK(
  FILTER(INDIRECT("Именованный_диапазон1"); INDIRECT("Именованный_диапазон1")<>"");
  FILTER(INDIRECT("Именованный_диапазон2"); INDIRECT("Именованный_диапазон2")<>"");
  FILTER(INDIRECT("Именованный_диапазон3"); INDIRECT("Именованный_диапазон3")<>"")
)

[Shigobik]

=REGEXMATCH($D5;JOIN("|";VSTACK(FILTER(INDIRECT("Именованный_диапазон1"); INDIRECT("Именованный_диапазон1")<>"");FILTER(INDIRECT("Именованный_диапазон2"); INDIRECT("Именованный_диапазон2")<>"");))

Типа так должно быть? Так у меня весь диапазон цветом опять выделил) + пустые строки
Я думал тут условие должно быть.
Если чел есть в обоих диапазонах Именованный_диапазон1 и Именованный_диапазон2, то только тогда выделять цветом. Если только в однои из них, то не должно выделять.
А это просто добавляет еще один диапазон для поиска, я правильно понял?

[Григорий Боев]

Если "И", то так:

=И(
  REGEXMATCH($D5;JOIN("|"; FILTER(INDIRECT("Именованный_диапазон1"); INDIRECT("Именованный_диапазон1")<>"")));
  REGEXMATCH($D5;JOIN("|"; FILTER(INDIRECT("Именованный_диапазон2"); INDIRECT("Именованный_диапазон2")<>"")))
)

[Shigobik]

Григорий Боев, работает хорошо, спасибо)
И последнее, если не сложно.
Выделить цветом в Именованный_диапазон1 если в Именованный_диапазон2 чела нет, а в Именованный_диапазон3 он есть.)

[Григорий Боев]

Точно так же

=И(
  НЕ(
    REGEXMATCH($D5;JOIN("|"; FILTER(INDIRECT("Именованный_диапазон2"); INDIRECT("Именованный_диапазон2")<>"")))
  );
  REGEXMATCH($D5;JOIN("|"; FILTER(INDIRECT("Именованный_диапазон3"); INDIRECT("Именованный_диапазон3")<>"")))
)

[Shigobik]

Григорий Боев, спасибо, большое)

Answer 2

[Александр]

Используйте REGEXMATCH.

Comments

[Shigobik]

=REGEXMATCH($D5;INDIRECT("Именованный_диапазон1");)
Чет ваще не работает...

[Александр]

Shigobik, адресация и синтаксис.

[Shigobik]

Александр, А че с ними?

[Александр]

Shigobik

Если искать только по столбцу D...

Для отладки формулы вставьте её в ячейку таблицы. (Будет сообщение об ошибке синтаксиса).

[Shigobik]

Александр,
MATCH($D5;INDIRECT("Именованный_диапазон1");)
Но так то она работает...

[Александр]

Shigobik

Вы же вроде давненько с Гугл Таблицами работаете — загляните в справку.

[Ziptar]

Александр, ну так судя по справке MATCH и REGEXMATCH общего имеют только "match" в названии, и больше ничего

[Shigobik]

У меня знаний ноль.
Зашел в справку, там написано, как формулу составлять. Увидел фразу "регулярное выражение" и все...
Понятия не имею че с этим делать...

[Александр]

Shigobik

Сравните эту формулу с формулой в справке.

=REGEXMATCH($D5;INDIRECT("Именованный_диапазон1");)

Вот иначе напишу:

=REGEXMATCH(
  $D5;
  INDIRECT("Именованный_диапазон1");
  ""
)

Всё ли правильно?

[Александр]

Ziptar, хм...

Скрытый текст

А как же количество параметров?

[Ziptar]

Александр, тогда уж количество обязательных параметров