Как в функцию QUERY добавить новые Col?

Question

[wwaavvyy]

Здравствуйте. Делаю перенос таблицы с на другой лист с форматированием. Подробнее об этом в моем предыдущем вопросе. Как разделить данные ячейки, перечисленные через запятую, и перенести на другой лист? Как это автоматизировать?
Моя изначальная таблица:

spoiler

То, что получилось после при помощи формулы:

spoiler

А вот и сама формула:

spoiler

Теперь мой вопрос (вернее, два):
1) Как сделать так, чтобы на новом листе были все столбцы из листа "Данные"?
2) Как исправить отображение данных в столбце Timestamp?

Ссылка на таблицу: https://docs.google.com/spreadsheets/d/1e53AE51FuJ...

Comments

[Alexander Ivanov]

Отправил запрос на доступ к Таблице

[wwaavvyy]

Alexander Ivanov, здравствуйте. Не нашел где запрос принять. Открыл всем доступ к редактированию. https://docs.google.com/spreadsheets/d/1e53AE51FuJ...

Answer 1

[kishkin]

P - это колонка за горизонтом, то есть буква, которая будет у самой правой колонки, если добавить ещё одну. У вас последняя имеющаяся - O. Поэтому следующая - P.

=QUERY(
  ARRAYFORMULA(
    {
      QUERY(
        FLATTEN(IFERROR(SPLIT('Данные'!B:B, ", ", 0))),
        "WHERE Col1 IS NOT NULL",
        0
      ),
      VLOOKUP(
        QUERY(
          FLATTEN(IF(IFERROR(SPLIT('Данные'!B:B, ", ", 0)) = "",, ROW('Данные'!A:A))),
          "WHERE Col1 IS NOT NULL",
          0
        ),
        {
          ROW('Данные'!A:A),
          'Данные'!A:A,
          'Данные'!C:P
        },
        SEQUENCE(1, COLUMNS('Данные'!C:P) + 1, 2),
        0
      )
    }
  ),
    "SELECT Col2, Col1, Col" & JOIN(", Col", SEQUENCE(1, COLUMNS('Данные'!C:P), 3)) & "
     FORMAT Col2 'yyyy-mm-dd hh:mm:ss'",
  1
)

Answer 2

[Alexander Ivanov]

Обновите до

=ARRAYFORMULA(QUERY((
  {
    QUERY(
      FLATTEN(IFERROR(SPLIT('Данные'!B:B, ", ", 0))),
      "WHERE Col1 IS NOT NULL",
      0
    ),
    VLOOKUP(
      QUERY(
        FLATTEN(IF(IFERROR(SPLIT('Данные'!B:B, ", ", 0)) = "",, ROW('Данные'!A:A))),
        "WHERE Col1 IS NOT NULL",
        0
      ),
      {
        ROW('Данные'!A:A),
        'Данные'!A:A,
        'Данные'!C:P
      },
      COLUMN('Данные'!B:P),
      0
    )
  }),
  "SELECT Col2, Col1, Col" & JOIN(", Col", COLUMN('Данные'!C:P)) & "
  FORMAT Col2 'yyyy-mm-dd hh:mm:ss'",
  1
))