Как прописать поворот текстуры в Unity-шейдере?

Question

[Данил Чекалин]

Имеется шейдер поставляемый Tiled2Unity:

// Upgrade NOTE: upgraded instancing buffer 'MyProperties' to new syntax.

Shader "Tiled2Unity/Default (Instanced)"
{
    Properties
    {
        _MainTex ("Tiled Texture", 2D) = "white" {}
        _Color ("Tint", Color) = (1,1,1,1)
        [MaterialToggle] PixelSnap ("Pixel snap", Float) = 0
    }

    SubShader
    {
        Tags
        { 
            "Queue"="Transparent"
            "IgnoreProjector"="True"
            "RenderType"="Transparent"
            "PreviewType"="Plane"
        }

        Cull Off
        Lighting Off
        ZWrite Off
        Fog { Mode Off }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass
        {
        CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile DUMMY PIXELSNAP_ON
            #include "UnityCG.cginc"
            #include "Tiled2Unity.cginc"

            struct appdata_t
            {
                float4 vertex   : POSITION;
                float4 color    : COLOR;
                float2 texcoord : TEXCOORD0;
                UNITY_VERTEX_INPUT_INSTANCE_ID
            };

            struct v2f
            {
                float4 vertex   : SV_POSITION;
                fixed4 color    : COLOR;
                half2 texcoord  : TEXCOORD0;
            };


            UNITY_INSTANCING_BUFFER_START(MyProperties)
                UNITY_DEFINE_INSTANCED_PROP(float4, _Color)
#define _Color_arr MyProperties
            UNITY_INSTANCING_BUFFER_END(MyProperties)

            v2f vert(appdata_t In)
            {
                UNITY_SETUP_INSTANCE_ID(In);

                v2f Out;
                Out.vertex = UnityObjectToClipPos(In.vertex);
                Out.texcoord = In.texcoord;
                Out.color = In.color * UNITY_ACCESS_INSTANCED_PROP(_Color_arr, _Color);

                #ifdef PIXELSNAP_ON
                Out.vertex = UnityPixelSnap (Out.vertex);
                #endif

                return Out;
            }

            sampler2D _MainTex;

            fixed4 frag(v2f In) : COLOR
            {
                half4 texcol = tex2D(_MainTex, In.texcoord);
                texcol = texcol * In.color;
                return texcol;
            }
        ENDCG
        }
    }

    Fallback "Sprites/Default"
}

Вот ренден:


Как реализовать случайный rotate на (0, 90, 180, 270 градусов) для материала? Хочу чтоб спрайт травы не был однообразным.

Comments

[Данил Чекалин]

Проще, но это экспорт из Tiled в Unity-prefab

[Даниил Басманов]

Данил Чекалин: Новый Tilemap не пробовали? Там это проще делается.

[Данил Чекалин]

Нет не пробовал. Но только, что глянул, и возможно он бы решил мою проблему (я бы брал все ячейки в нужном слои и пробежался бы по ним, и менял transform.rotate), но Tiled нужен для геимдизайнера. По-этому переход на внутренний Tilemap отменяется в данным момент. Я HLSL ранее ни когда не работал, но я думаю это задача весьма проста для тех, кто шарит в шейдерах.

[Данил Чекалин]

Даниил Басманов, спасибо за Tilemap, обязательно в будущем попробую его

[Даниил Басманов]

Данил Чекалин, Так а зачем ему Tiled, если в юнити можно всё то же самое сделать? В юнити скорость итерации всяко больше будет.

[Данил Чекалин]

Даниил Басманов, в Unity при использование Tilemap отсутствует вменяемая поддержка работа с коллайдерами. В Tiled я могу коллайдер назначать на уровне тайла, и в последующем при установки такого тайла на карту, коллайдеры будут добавлены в импорт (Tiled2Unity).

Answer 1

[Даниил Басманов]

Для вашей проблемы есть несколько решений. Самое простое - добавить в атлас три повёрнутых картинки травы и использовать их в кисти, которая рисует случайными тайлами. Так вы в будущем сможете перерисовать графику без пересборки карты и вам не придётся поддерживать специальные шейдеры или руками вращать что-то на сцене.

Второе по простоте решение - воспользоваться возможностями Tiled и вращать тайлы там, Tiled это умеет, Tiled2Unity тоже, скорее всего.

Если же прям сильно хотите шейдером, то можно, например, с помощью двух флагов поворачивать uv во все четыре стороны.

Custom/RotationExample

Shader "Custom/RotationExample"
{
    Properties
    {
        _MainTex("Texture", 2D) = "white" {}

        // Волшебные свойства для инспектора
        [Toggle] _RotateCW90("Rotate Clockwise 90", Float) = 0.0
        [Toggle] _Rotate180("Rotate 180", Float) = 0.0
        ////////////////////////////////////
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" "PreviewType" = "Plane" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            // Флаги для компиляции нескольких вариантов шейдера
            #pragma multi_compile __ _ROTATECW90_ON
            #pragma multi_compile __ _ROTATE180_ON
            ////////////////////////////////////////////////////
            
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float2 uv : TEXCOORD0;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            
            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {

                // Собственно код вращения uv
#if _ROTATECW90_ON
                i.uv = float2(1 - i.uv.y, i.uv.x);
#endif
#if _ROTATE180_ON
                i.uv = float2(1 - i.uv.x, 1 - i.uv.y);
#endif
                /////////////////////////////

                fixed4 color = tex2D(_MainTex, i.uv);
                return color;
            }
            ENDCG
        }
    }
}

Я комментариями пометил три важных кусочка, которые можно засунуть в любой шейдер для вращения текстуры. Код выше работает только для квадов с простейшей квадратной uv-картой, растянутой на весь диапазон от нуля до единицы, для атласов надо придумывать другое решение. Ну и не забывайте, что эти флаги надо будет как-то выставлять.

Comments

[Данил Чекалин]

Спасибо. Остановлюсь с вариантом вращения внутри Tiled.

[Данил Чекалин]

Тем не менее, хочу понять. Есть меш, который заливается материалом, в данном случаи спрайтом 32х32. Шейдер может при заливки работать с отдельными блоками заливки, то есть например повернуть 3 дубликат материала слева в первой линии?

[Данил Чекалин]

BTW, https://assetstore.unity.com/packages/tools/sprite... , но поддержки коллайдеров нет вроде

[Даниил Басманов]

Данил Чекалин, Шейдер про материалы ничего не знает, только материал знает про шейдер. А про материалы знает рендерер. Для работы с отдельными блоками заливки вам нужно либо использовать Renderer.SetPropertyBlock, либо выставлять нужные материалы, которые вы заранее настроили.