Как в скрипт на vbs добавить проверку?

Question

[Dmitry]

Здравствуйте!
Помогите пожалуйста улучшить скрипт ( VBS):

On Error Resume Next
Set objSysInfo = CreateObject("ADSystemInfo")
Set objNetwork = CreateObject("WScript.Network")
Set objUser = GetObject("LDAP://" & objSysInfo.UserName)
objUser.Put "wWWHomePage", objNetwork.ComputerName
objUser.SetInfo

нужно добавить условие.
Если условие выполнено, то записать в атрибут wWWHomePage имя компьютера на котором был запущен скрипт.
В условии нужно сделать проверку, является ли компьютер членом группы "запрет wWWHomePage", если является, то завершить выполнение скрипта, а если нет - выполнить.
Спасибо!

Answer 1

[Александр Ананьев]

Как-то так подсказывает гугл

Comments

[Dmitry]

дело в том, что в vbs я совсем ни как (

[Александр Ананьев]

Janus74: А в чем вы как?
Берете функцию Function IsComputerMemberOf(objComputerToCheck, strGroupName) из ссылки. Далее пишите условие

Dim objComputer
Set objComputer = GetObject("LDAP://" & objSysInfo.ComputerName )
If IsComputerMemberOf(objComputer, "запрет wWWHomePage") Then
objUser.Put "wWWHomePage", objNetwork.ComputerName
End if

[Dmitry]

Александр: спасибо, оставлю результат здесь:
Dim objComputer
Set objSysInfo = CreateObject("ADSystemInfo")
Set objNetwork = CreateObject("WScript.Network")
Set objUser = GetObject("LDAP://" & objSysInfo.UserName)
Set objComputer = GetObject("LDAP://" & objSysInfo.ComputerName )
If not IsComputerMemberOf(objComputer, "wWWHomePage") Then
objUser.Put "wWWHomePage", objNetwork.ComputerName
objUser.SetInfo
End if
Function IsComputerMemberOf(objComputerToCheck, strGroupName)
Dim arrComputerGroups
Dim strComputerGroup

' Initiate as False
IsComputerMemberOf = False

On Error Resume Next
arrComputerGroups = objComputerToCheck.memberOf
If Err.Number <> 0 Then
Exit Function
End If

If IsArray(arrComputerGroups) Then
For Each strComputerGroup In arrComputerGroups
If InStr(strComputerGroup, strGroupName) > 0 Then
IsComputerMemberOf = True
Exit Function
End If
Next
Else
strComputerGroup = arrComputerGroups
If Not IsEmpty(strComputerGroup) Then
If InStr(strComputerGroup, strGroupName) > 0 Then
IsComputerMemberOf = True
End If
End If
End If
End Function ' End IsComputerMemberOf