Как написать формулу чтоб из диапазона достать уникальные значения в один столбец?

Question

[Shigobik]

Условно есть таблица на несколько столбцов. Мне нужно из диапазона, например, А:В достать все уникальные значения. Необязательно, но желательно их еще и подсчитать: каждое значение в соседнюю колонку.

Я пробовал использовать такую вот формулу: =UNIQUE(A:B)
Но она в один столбец не засовывает, а так же выводит в два столбца, что не нужно.

Пробовал и такую:

=QUERY(A:B; "SELECT B, COUNT(B) WHERE B IS NOT NULL GROUP BY B")

Но не знаю, как сюда засунуть два столбца. Хоть диапазон и прописан, берёт всё равно из одного столбца, а не из обоих.

Answer 1

[Григорий Боев]

TOCOL делает столбец из данных.

=QUERY(
  TOCOL(A:B);
  "SELECT Col1, COUNT(Col1)
    WHERE Col1 IS NOT NULL
    GROUP BY Col1
    ORDER BY COUNT(Col1) DESC
    LABEL Col1 'Кто', COUNT(Col1) 'Кол-во'
  "
)

Comments

[Shigobik]

Ммм, вроде работает как надо.
А как можно убрать заголовки "кто" и "кол-во"?
Просто удалил, сломалась формула...
И еще момент, если скажем нужно не все значения диапазона, а определенные, например только те ячейки, которые содержат определнный символ или слово?

[Григорий Боев]

Уберите подписи в запросе
LABEL Col1 'Кто', COUNT(Col1) 'Кол-во'
, но вернутся стандартные подписи, вроде count(Col1)

только те ячейки, которые содержат определнный символ или слово

TOCOL(A:B) замените на FILTER(TOCOL(A:B); "тут ваш фильтр к TOCOL(A:B). Например через REGEXP")

[Shigobik]

=QUERY( FILTER(TOCOL(A:B);"4");"SELECT Col1, COUNT(Col1) WHERE Col1 IS NOT NULL GROUP BY Col1 ORDER BY COUNT(Col1) DESC LABEL Col1 'Кто', COUNT(Col1) 'Кол-во'")

Типа так? Ток она у меня не работает...
Ошибка
В функции FILTER указан неверный диапазон. Требуемое число строк – 101000, столбцов – 1. Фактическое число строк – 1, столбцов – 1

[Григорий Боев]

Shigobik, нет, не так. 2й параметр FILTER() - массив такого же размера как первый параметр. Если там true - значение остаётся в выдаче. Можно не FILTER применять, а прямо в SQL запросе сделать:
WHERE Col1 LIKE '%паттерн%'