Как в Google Sheets настроить перенос уникальной информации с одного листа на другой, посредством выполнения условий?

Question

[Sunrayzen]

Добрый день!

Суть вопроса следующая

Нужно чтобы из одного листа (лист 2), передавалась уникальная информация о конкретном студенте, по дате (B) и месту проведения занятия (C) в лист 1, столбец "P" горизонтально. Каждый раз уникальная операция к пользователю

Верно ли я понимаю, что нужно работать через форму Unique, Filter?

Как выглядят таблицы:
Лист 1


Лист 2

Answer 1

[Григорий Боев]

Со скринами работать неудобно, лучше прилагайте таблицу с исходными данными (без личной информации)
А формула примерно такая:

=arrayformula(let(
 students_lookup; a2:a;
 
 students; Лист2!a2:a;
 dates; Лист2!b2:b;
 spots; Лист2!c2:c;
 
 find_students_records;lambda(student;join(";";filter(dates&" "&spots;students=student)));
 out;byrow(students_lookup;find_students_records);
 
 if(students_lookup="";;out) 
))

Comments

[Sunrayzen]

Благодарю за ответ и оперативность, Григорий!

Возможно я немного не так изъяснился, планировал, чтобы каждая отдельная дата и место проведения (спот), соответствовали только 1 ячейке а не были через ";" в рамках одной ячейки

Т.е, 1 операция в таблице ввод (если есть дата и спот) заполняется в пустую ячейку к соответствующему студенту

Ссылка на таблицу: https://docs.google.com/spreadsheets/d/1J9sELPxuQW...

Есть ли возможность адаптировать ваше предложение под предложенные условия? Какие манулы можно изучить?

[Григорий Боев]

тогда надо убрать join()

=arrayformula(let(
 students_lookup; a2:a;
 
 students; Лист2!a2:a;
 dates; Лист2!b2:b;
 spots; Лист2!c2:c;
 
 find_students_records;lambda(student;filter(dates&" "&spots;students=student));
 out;byrow(students_lookup;find_students_records);
 
 if(students_lookup="";;out) 
))

[Sunrayzen]

Григорий Боев, Сделал, действительно одной ячейке соответствует 1 дата и место, но далее не продолжает обновлять если в таблице "Вводить" более одного упоминания студента

Смысл таблицы "Вводить" (Лист 2), в том чтобы начислять студенту баланс и списывать с него его, когда проводится занятие, т.е упоминаний будет несколько

Доступ редактора предоставил к таблице

[Sunrayzen]

Григорий Боев, Извиняюсь, вот актуальная ссылка, возникли сложности с доступом: https://docs.google.com/spreadsheets/d/1J9sELPxuQW...

[Григорий Боев]

Sunrayzen,

=arrayformula(let(
 students_lookup; A2:A;
 
 students; 'Вводить'!A2:A;
 dates_; 'Вводить'!B2:B;
 dates; ЕСЛИ(dates_="";"";ТЕКСТ(dates_;"yyyy-MM-dd"));
 spots; 'Вводить'!C2:C;
 
 find_students_records;lambda(student;join(";";filter(dates&" "&spots;students=student;dates<>"")));
 out;byrow(students_lookup;find_students_records);
 
 ЕСЛИ(students_lookup="";;IFERROR(SPLIT(out;";"))) 
))