Google таблицы: трансформация текста в дату и время, как?

Question

[tihi]

Пример текста, который надо переделать в дату и время - January 07, 2021 at 08:31PM, как этому придать такой вид: 20:31, 07.01.2020?

Answer 1

[Alexander Ivanov]

Возможно,

=DATE(
  REGEXEXTRACT(A1,"(\d{4})"),
  SWITCH(REGEXEXTRACT(A1,"\w{3}"),"Jan",0,"Feb",1,"Mar",2,"Apr",3,"May",4,"Jun",5,"Jul",6,"Aug",7,"Sep",8,"Oct",9,"Nov",10,"Dec",11),
  REGEXEXTRACT(A1,"(\d{2}),")
)
+
TIME(
  IF(REGEXMATCH(A1,"PM"),12,0)+REGEXEXTRACT(A1,"(\d{2}):"),
  REGEXEXTRACT(A1,":(\d{2})"),
  0
)

К сожалению, всё это сильно зависит от формата строки.

Формула для массива

=ARRAYFORMULA(
  DATE(
    REGEXEXTRACT(A1:A12,"(\d{4})"),
    SWITCH(REGEXEXTRACT(A1:A12,"\w{3}"),"Jan",0,"Feb",1,"Mar",2,"Apr",3,"May",4,"Jun",5,"Jul",6,"Aug",7,"Sep",8,"Oct",9,"Nov",10,"Dec",11),
    REGEXEXTRACT(A1:A12,"(\d{2}),")
  )
  +
  TIME(
    IF(REGEXMATCH(A1:A12,"PM"),12,0)+REGEXEXTRACT(A1:A12,"(\d{2}):"),
    REGEXEXTRACT(A1:A12,":(\d{2})"),
    0
  ))

Возможно, SWITCH - не лучшая идея. Можно заменить на MATCH

=ARRAYFORMULA(
  DATE(
    REGEXEXTRACT(A2:A100;"(\d{4})");
    MATCH(REGEXEXTRACT(A2:A100;"\w{3}");{"Jan";"Feb";"Mar";"Apr";"May";"Jun";"Jul";"Aug";"Sep";"Oct";"Nov";"Dec"};0)-1;
    REGEXEXTRACT(A2:A100;"(\d{2}),")
  )
 +
  TIME(
    IF(REGEXMATCH(A2:A100;"PM");12;0)+REGEXEXTRACT(A2:A100;"(\d{2}):");
    REGEXEXTRACT(A2:A100;":(\d{2})");
    0
  )
 )

Comments

[tihi]

Здоровский пример. Но что-то не могу никак победить задачку, что только не пробовал(((

[Alexander Ivanov]

tihi, пришлите пример ваших данных - это самый быстрый способ решения.

[Alexander Ivanov]

tihi, скорее всего вместо запятых должны быть точки с запятыми - разделители в разных локациях разные https://github.com/hedgehogsburrows/google-sheets-...

[tihi]

Спасибо огромное! Вы мне очень помогли!!! Всего Вам самого, самого!!!

Answer 2

[Александр]

Я «парсил» такой формат с помощью функций REGEXTRACT(), MATCH() (для замены названия месяца на его номер), RIGHT(), LEFT(), IF() (для проверки AM/PM). Так как получаемого текста в виде даты мне было достаточно, то DATEVALUE() не использовал.