Assembler как работать со спикером на прямую?

Question

[Типа Программист]

Я пишу маленькую ОС, чисто поучить ассемблер. В ОС я не могу использовать прерывания доса, поэтому такой вопрос как работать со спикером, например как заставить его пищать. Вроде и гугл есть но там как-то сложно показано это все и замудрено, понял только что 60h вроде как отвечает за спикер.

Answer 1

[Сергей Горностаев]

На голом железе придётся использовать порты

MOV     DX, 2000         ; Number of times to repeat whole routine.

MOV     BX, 1            ; Frequency value.

MOV     AL, 10110110B    ; The Magic Number (use this binary number only)
OUT     43H, AL          ; Send it to the initializing port 43H Timer 2.

NEXT_FREQUENCY:          ; This is were we will jump back to 2000 times.

MOV     AX, BX           ; Move our Frequency value into AX.

OUT     42H, AL          ; Send LSB to port 42H.
MOV     AL, AH           ; Move MSB into AL  
OUT     42H, AL          ; Send MSB to port 42H.

IN      AL, 61H          ; Get current value of port 61H.
OR      AL, 00000011B    ; OR AL to this value, forcing first two bits high.
OUT     61H, AL          ; Copy it to port 61H of the PPI Chip
                         ; to turn ON the speaker.

MOV     CX, 100          ; Repeat loop 100 times
DELAY_LOOP:              ; Here is where we loop back too.
LOOP    DELAY_LOOP       ; Jump repeatedly to DELAY_LOOP until CX = 0


INC     BX               ; Incrementing the value of BX lowers 
                         ; the frequency each time we repeat the
                         ; whole routine

DEC     DX               ; Decrement repeat routine count

CMP     DX, 0            ; Is DX (repeat count) = to 0
JNZ     NEXT_FREQUENCY   ; If not jump to NEXT_FREQUENCY
                         ; and do whole routine again.

                         ; Else DX = 0 time to turn speaker OFF

IN      AL, 61H          ; Get current value of port 61H.
AND     AL, 11111100B    ; AND AL to this value, forcing first two bits low.
OUT     61H, AL          ; Copy it to port 61H of the PPI Chip
                         ; to turn OFF the speaker.

Здесь подробно описано, как это работает.

Comments

[Типа Программист]

Ех и в итоге ничего не понятно, да большинство иза моей тупости, но все-же

MOV     AL, 10110110B    ; The Magic Number (use this binary number only)

Как мне это понять...

[Сергей Горностаев]

MegaCraZy6, по ссылкам вы явно не ходили. Инициализация таймера для генерации square-wave pulse

One
        Pulse
       |     |
 +     +-----+     +-----+     +-----+
       !     !     !     !     !     !
 0 ----+     +-----+     +-----+     +----  <-- Wave form sent to the Speaker
.
       |     |
       |   "gate"
       |    is turned OFF here
     "gate"
      is turned ON here

43H  Write: set channel's mode of operation
      ╓7┬6┬5┬4┬3┬2┬1┬0╖
      ║ch#│r/l│mode │ ║
      ╙─┴─┴─┴─┴─┴─┴─┴╥╜ bits mask
       └╥┘ └╥┘ └─╥─┘ ╚═►  0: 01H 0=process count as binary
        ║   ║    ║               1=process counts as BCD▲
        ║   ║    ╚═════►1-3: 0eH select timer mode:
        ║   ║                    000 = mode 0: interrupt on terminal count
        ║   ║                    001 = mode 1: programmable one-shot
        ║   ║                    x10 = mode 2: rate generator
        ║   ║                    x11 = mode 3: square-wave rate generator
        ║   ║                    100 = mode 4: software-triggered strobe
        ║   ║                    101 = mode 5: hardware-triggered strobe
        ║   ╚══════════►4-5: 30H select read/load sequence:
        ║                        00 = latch counter for stable read
        ║                        01 = read/load most significant byte only
        ║                        10 = read/load least significant byte only
        ║                        11 = read/load LSB then MSB
        ╚══════════════►6-7: c0H specify counter to affect:
                                 00 = counter 0, 01= counter 1
                                 10 = counter 2, 11= counter 3

Answer 2

[jcmvbkbc]

www.techhelpmanual.com/903-pc_sounds___speaker_sup...