Как сделать подсчёт данных за определённые промежутки времени?

Question

[Николай Осипенко]

Существует таблица, в столбце которой исполнители ставят свою фамилию из раскрывающего списка по факту выполнения соответствующего строке задания. В другой вкладке создал статистику, в которой мне необходимо отразить сколько каждая фамилия появилась в том столбце сегодня, за текущую неделю, месяц.
Пока что сделал общую накопительную картину по каждому специалисту.

Comments

[Sergey_USB]

Пример добавь, не совсем понятно что ты хочешь получить и из чего.

[Александр]

Почему вы должны создать пример.

[Николай Осипенко]

Сотрудники в этой таблице отмечают свою фамилию, когда выполняют конкретную задачу. Не обязательно каждый день, а только тогда, когда выполнят её.


А в этой таблице я вижу, что Иванов сегодня завершил одну задачу, за текущую неделю - две, за текущий месяц - две, всего - две. Завтра будет первое число, и столбцы "Сегодня" и "За месяц" обнулятся, а в Пн в полночь обнулятся "Сегодня" и "За неделю".


Вот как это сделать? Я уже всю голову сломал

[Александр]

Николай Осипенко, представленных на изображениях таблиц недостаточно, чтобы понять и решить ваш случай.

Answer 1

[Alexander Ivanov]

Следующее решение скорее вредно, чем полезно. Но т.к. автор не сделал должного примера, то тем самым развязал руки.

И так, через MAP можно получить данные для расчета

=MAP(C2:C17;LAMBDA(X;JOIN("|";N(X=TODAY());N(WEEKNUM(TODAY())=WEEKNUM(X));N(EOMONTH(TODAY();0)=EOMONTH(X;0));1)))

Дальше дело за малым -- разбить на поля и произвести подсчет группировкой

=ARRAYFORMULA(QUERY(
  {B2:B17\SPLIT(MAP(C2:C17;LAMBDA(X;JOIN("|";N(X=TODAY());N(WEEKNUM(TODAY())=WEEKNUM(X));N(EOMONTH(TODAY();0)=EOMONTH(X;0));1)));"|")};
  "select Col1, sum(Col2), sum(Col3), sum(Col4), sum(Col5)
     group by Col1
       label Col1'Исполнитель',sum(Col2)'Сегодня',sum(Col3)'За неделю',sum(Col4)'За месяц',sum(Col5)'Всего'";
  0
))

Пример в Таблице https://docs.google.com/spreadsheets/d/13gegj_POL7...

2022-10-04 Обновлено.
Сравнение дат через DATEDIFF требует очередь аргументов, поэтому лучше сравнивать номера недель. Но тогда отчет будет выводить не за 7 дней, а именно за неделю.

Comments

[Николай Осипенко]

Я просто не понимаю чего в моём примере не хватает. Наверное, вы нашли решение, надо разобраться, для меня это прям дебри какие-то, на первый взгляд) Но всё равно спасибо! По результату отпишусь

[Николай Осипенко]

Посмотрел решение. К сожалению, в моей таблице нет дат. Возможно ли как-то автоматически фиксировать даты? Поставил исполнитель свою фамилию, и дата зафиксировалась.

[Alexander Ivanov]

Николай Осипенко, проблема вашего примера в том, что его нет. Это просто картинки. Почему нужно сделать пример

Да, вам нужны даты. Фиксировать можно. Например, через скрипты.

[Николай Осипенко]

Alexander Ivanov, спасибо, я здесь новичок, теперь понял, что такое пример.
Со скриптом дат я справился, с подсчётом в столбец через "|" тоже. Но как разбить - не пойму. Тем более, у меня же несколько вкладок с данными... Делаю точно так, как у вас, но не получается(

https://docs.google.com/spreadsheets/d/1TMNV1HagJy...

[Alexander Ivanov]

Николай Осипенко, так вы не должны сами заполнять заголовки - формула все делает сама

[Alexander Ivanov]

Николай Осипенко, добавил пример в основную Таблицу https://docs.google.com/spreadsheets/d/13gegj_POL7...

[Николай Осипенко]

Alexander Ivanov, спасибо! Всё получилось, но не считает Сегодня, почему-то. Хоть и все даты стоят сегодняшние

[Alexander Ivanov]

Николай Осипенко, обновил формулу в Таблице

[Николай Осипенко]

Alexander Ivanov, Спасибо вам огромное! Теперь всё так, как и задумано! Просто супер! Жаль, конечно, что я не до конца понял этих формул. Но ничего, всё впереди.
Кстати, формула считает неделю и месяц календарные? Или отсчитывает семь дней и 30 дней со дня создания формулы?

[Alexander Ivanov]

Николай Осипенко, календарные. Т.е. сравнивает номера недель и начала месяцев соответственно. Чтобы сравнить периоды, нужно вписать что-то вроде N(MOD(TODAY()-X)<=7), N(MOD(TODAY()-X)<=30)

Answer 2

[Александр]

См. СЧЁТЕСЛИМН (COUNTIFS).